mirror of
https://gitlab.com/Anson-Projects/projects.git
synced 2025-06-16 06:56:46 +00:00
151 lines
7.4 KiB
Plaintext
151 lines
7.4 KiB
Plaintext
---
|
|
title: "ISS Eclipse Determination"
|
|
description: |
|
|
Determining how much sunlight a body orbiting a planet is receiving.
|
|
draft: false
|
|
author:
|
|
- name: Anson Biggs
|
|
url: https://ansonbiggs.com
|
|
repository_url: https://gitlab.com/lander-team/air-prop-simulation
|
|
date: 05-01-2021
|
|
fig_width: 6
|
|
fig_align: "center"
|
|
output:
|
|
distill::distill_article:
|
|
self_contained: false
|
|
categories:
|
|
- Julia
|
|
- Astrodynamics
|
|
bibliography: citations.bib
|
|
creative_commons: CC BY
|
|
preview: preview.png
|
|
---
|
|
|
|
Determining the eclipses a satellite will encounter is a major driving factor when designing a mission in space. Thermal and power budgets have to be made with the fact that a satellite will periodically be in the complete darkness of space with no solar radiation to power the solar panels and keep the spacecraft from freezing.
|
|
|
|
```{r setup, include=FALSE}
|
|
knitr::opts_chunk$set(echo = TRUE, results = 'hide')
|
|
library(JuliaCall)
|
|
julia_setup(JULIA_HOME = "/opt/julia-1.6.0/bin/")
|
|
```
|
|
|
|
## What is an Eclipse
|
|
|
|
|
|
|
|
The above image is a simple representation of what an eclipse is. You'll notice there is the Umbra which is complete darkness, then the Penumbra which is a shadow of varying darkness, and then the rest of the orbit is in complete sunlight. For this example I will be using the ISS which has a very low orbit so the Penumbra isn't much of a problem. You can tell by looking at the diagram that higher altitude orbits would spend more time in the Penumbra.
|
|
|
|
|
|
|
|
Here is a more detailed view of the eclipse that will make it easier to explain the code. There are 2 Position vectors and 2 radius's that need to be known for simple eclipse determination. There are more advanced cases where the atmosphere of the body your orbiting can greatly affect the Umbra and Penumbra, and other bodies could also potentially block the Sun, but for this example we will keep it simple since those have very little affect for the ISS's orbit. <code style="color:#0b7285">Rsun</code> and <code style="color:#c92a2a">Rbody</code> are the radius's of the Sun and Body (In this case Earth) respectively. <code style="color:#5f3dc4">r_sun_body</code> is a vector from the center of the Sun to the center of the target body. For this example I will only be using one vector, but for more rigorous eclipse determination its important to calculate this at least once a day since it does significantly change over the course of a year. The reason that I am ignoring it at the moment is because there is currently no good way to calculate [Ephemerides](https://ssd.jpl.nasa.gov/?ephemerides) in Julia but the package is being worked on so I may revisit this and do a more rigorous analysis in the future. <code style="color:#5c940d">r_body_sc</code> is a position vector from the center of the body being orbitted, to the center of our spacecraft.
|
|
|
|
## The Code
|
|
|
|
```{julia, code_folding=TRUE}
|
|
using Unitful
|
|
using LinearAlgebra
|
|
using SatelliteToolbox
|
|
using Plots
|
|
using Colors
|
|
theme(:ggplot2)
|
|
```
|
|
|
|
In order to get the orbit for the ISS I used a [Two-Line Element](https://en.wikipedia.org/wiki/Two-line_element_set) which is a data format for explaining orbits. the US Joint Space Operations Center makes these widely available, but https://live.ariss.org/tle/ makes the TLE for the ISS way more accessible [@ariss]. The Julia Package [SatelliteToolbox.jl](https://github.com/JuliaSpace/SatelliteToolbox.jl) makes it super easy to turn a TLE into an orbit that can be propagated. Simply putting the TLE in a string and using the `tle` string macro like below and now we have access to the information to start making our ISS orbit.
|
|
|
|
```{julia, results='show'}
|
|
ISS = tle"""
|
|
ISS (ZARYA)
|
|
1 25544U 98067A 21103.84943184 .00000176 00000-0 11381-4 0 9990
|
|
2 25544 51.6434 300.9481 0002858 223.8443 263.8789 15.48881793278621
|
|
"""
|
|
```
|
|
|
|
Now that we have the TLE we can pass that into SatelliteToolbox's orbit propagator. Before we can propagate the orbit we need to have a range of time steps to pass into the propagator. The TLE gives the mean motion, n, which is the revolutions per day so using that we can calculate the amount of time required for one orbit which is all that were worried about for this analysis. The propagator returns a tuple containing the Orbital elements, a position vector with units meters, and a velocity vector with units meters per second. For this analysis were only worried about the position vector.
|
|
|
|
```{juliam result='show'}
|
|
ISS[1].n
|
|
```
|
|
|
|
```{julia}
|
|
orbit = init_orbit_propagator(Val(:twobody), ISS[1]);
|
|
time = 0:0.1:((24 / ISS[1].n) .* 60 * 60); # ISS[1].n gives the mean motion, or orbits per day.
|
|
o, r, v = propagate!(orbit, time);
|
|
```
|
|
|
|
Now we just need way to use the radii and vectors discussed earlier to determine if the ISS is in the penumbra or umbra. This is a lot of pretty basic trigonometry and vector math.
|
|
|
|
`add more discussion about the math`
|
|
|
|
```{julia}
|
|
function sunlight(Rbody, r_sun_body, r_body_sc)
|
|
Rsun = 695_700u"km"
|
|
|
|
hu = Rbody * norm(r_sun_body) / (Rsun - Rbody)
|
|
|
|
θe = acos((r_sun_body ⋅ r_body_sc) / (norm(r_sun_body) * norm(r_body_sc)))
|
|
|
|
θu = atan(Rbody / hu)
|
|
du = hu * sin(θu) / sin(θe + θu)
|
|
|
|
θp = π - atan(norm(r_sun_body) / (Rsun + Rbody))
|
|
dp = Rbody * sin(θp) / cos(θe - θp)
|
|
|
|
S = 1
|
|
if (θe < π / 2) && (norm(r_body_sc) < du)
|
|
S = 0
|
|
end
|
|
if (θe < π / 2) && ((du < norm(r_body_sc)) && (norm(r_body_sc) < dp))
|
|
S = (norm(r_body_sc .|> u"km") - du) / (dp - du) |> ustrip
|
|
end
|
|
|
|
return S
|
|
end
|
|
```
|
|
|
|
Then we can pass all the values we've gathered into the function we just made.
|
|
|
|
```{julia}
|
|
S = r .|> R -> sunlight(6371u"km", [0.5370, 1.2606, 0.5466] .* 1e8u"km", R .* u"m");
|
|
```
|
|
|
|
## Plotting the Results
|
|
|
|
The `sunlight` function returns values from 0 to 1, 0 being complete darkness, 1 being complete sunlight, and anything between being the fraction of light being received. Again since the ISS has a very low orbit, the amount of time spend in the penumbra is almost insignificant.
|
|
|
|
```{julia, code_folding=TRUE, results='show',layout="l-body-outset",fig.cap= "ISS Sunlight", preview=TRUE }
|
|
# Get fancy with the line color.
|
|
light_range = range(colorant"black", stop = colorant"orange", length = 101);
|
|
light_colors = [light_range[unique(round(Int, 1 + s * 100))][1] for s in S];
|
|
|
|
plot(
|
|
LinRange(0, 24, length(S)),
|
|
S .* 100,
|
|
linewidth = 5,
|
|
legend = false,
|
|
color = light_colors,
|
|
);
|
|
|
|
xlabel!("Time (hr)");
|
|
ylabel!("Sunlight (%)");
|
|
title!("ISS Sunlight Over a Day")
|
|
```
|
|
|
|
Looking at the plot its pretty easy to see by the vertical transition from 0% to 100% that the time in the penumbra is limited, but almost counterintutively it also looks like the ISS gets more sunlight than it does darkness. Using the raw sunlight data we can actually calculate almost exactly how much time is spent in each region.
|
|
|
|
Time in Sun:
|
|
```{julia, results='show'}
|
|
sun = length(S[S.==1])/length(S) * 100
|
|
```
|
|
|
|
Time in Darkness:
|
|
```{julia, results='show'}
|
|
umbra = length(S[S.==0])/length(S) * 100
|
|
```
|
|
|
|
Time in Penumbra:
|
|
```{julia, results='show'}
|
|
penumbra = 100 - umbra - sun
|
|
```
|
|
|
|
The ISS spends about 62% of its time in the sun, this is because if you go back and reference the diagram at the beginning of this post you can see that the umbra is actually a cone. This is mainly due to the fact that the Sun is massive compared to the Earth, but this effect is also stronger with orbits of higher altitudes.
|